**3.25. Контактная информация**

Подсистема «Контактная информация» позволяет расширять состав реквизитов объекта произвольным набором реквизитов контактной информации (КИ). Реквизиты КИ могут быть как предопределенными (адреса, телефоны, факс, e-mail, www), так и пользовательскими (например, «телефон с 18:00 до 24:00»). Справочник со встроенной контактной информацией называется владельцем КИ.

Важно!

В российской версии библиотеки вид КИ Адрес использует возможности подсистемы «Адресный классификатор». Основной режим использования подсистемы предполагает, что в конфигурацию также переносится подсистема «Адресный классификатор».

**Настройка**

После выполнения переноса объектов библиотеки необходимо включить в командный интерфейс конфигурации справочники:

* ● ВидыКонтактнойИнформации,
* ● Страны мира.

Настройка объектов подсистемы сводится к созданию в справочнике ВидыКонтактнойИнформации предопределенных элементов и вызову обработчика обновления информационной базы, использующего процедуру УстановитьСвойстваВидаКонтактнойИнформации из модуля УправлениеКонтактнойИнформацией, для установки значения реквизитов этих элементов.

1. Принять решение по поводу состава объектов – владельцев контактной информации и видов контактной информации у каждого такого объекта. Например, у справочника КонтактныеЛица необходимо разместить телефон и адрес, а у справочника Контрагент – адрес электронной почты.

2. Добавить ссылки на объекты-владельцы (кроме документов) в состав определяемого типа ВладелецКонтактнойИнформации.

3. Добавить ссылки на документы-владельцы в подписку на событие ЗаполнитьКонтактнуюИнформациюДокумента.

4. Перечислить виды контактной информации в справочнике ВидыКонтактнойИнформации. Справочник видов контактной информации – иерархический.

* ● На первом уровне вводятся предопределенные группы: для каждого вида объекта – владельца контактной информации – своя группа. У группы должно быть задано имя в формате Справочник<ИмяСправочника> или Документ<ИмяДокумента>. Например, для справочника физических лиц – СправочникФизическиеЛица. Наименование группы рекомендуется задавать в виде: Контактная информация справочника "Физические лица".
* ● На втором уровне вводятся элементы – виды контактной информации, список которых определяет разработчик конфигурации. На втором уровне могут быть также заведены предопределенные группе, если предполагается хранение контактной информации для табличной части объекта. В этом случае у группы должно быть задано имя в формате Документ<ИмяСправочника><ИмяТабличнойЧасти>.
* ● На третьем уровне вводятся элементы – виды контактной информации для табличной части объекта. Список видов контактной информации определяет ответственный за конфигурацию.

5. Добавить обработчик обновления информационной базы, предназначенный для первоначального заполнения значения реквизитов, предопределенных видов КИ при помощи процедуры УстановитьСвойстваВидаКонтактнойИнформации модуля УправлениеКонтактнойИнформацией.

6. Для предопределенных групп контактной информации необходимо установить свойство Используется в значение Истина. Подробнее см. раздел [Отключение неиспользуемых видов контактной информации](https://its.1c.ru/db/content/bsp301doc/src/3.25.%20%D0%BA%D0%BE%D0%BD%D1%82%D0%B0%D0%BA%D1%82%D0%BD%D0%B0%D1%8F%20%D0%B8%D0%BD%D1%84%D0%BE%D1%80%D0%BC%D0%B0%D1%86%D0%B8%D1%8F.htm?_=1542292879#_отключение_неиспользуемых_видов).

Пример процедуры обновления информационной базы:

// Процедура обновления ИБ для справочника видов контактной информации

Процедура КонтактнаяИнформацияОбновлениеИБ() Экспорт

// Справочник "Контрагенты"

ПараметрыВида = УправлениеКонтактнойИнформацией.ПараметрыВидаКонтактнойИнформации(Перечисления.ТипыКонтактнойИнформации.Адрес);

ПараметрыВида.Вид = Справочники.ВидыКонтактнойИнформации.\_ДемоАдресКонтрагента;

ПараметрыВида.Используется = Истина;

ПараметрыВида.МожноИзменятьСпособРедактирования = Истина;

ПараметрыВида.Порядок = 1;

ПараметрыВида.НастройкиПроверки.ТолькоНациональныйАдрес = Истина;

ПараметрыВида.НастройкиПроверки.ПроверятьКорректность = Истина;

УправлениеКонтактнойИнформацией.УстановитьСвойстваВидаКонтактнойИнформации(ПараметрыВида);

КонецПроцедуры

Для  обновления значений реквизитов необходимо использовать отложенный обработчик обновления. Примеры использования таких обработчиков см. в общем модуле \_ДемоОбновлениеИнформационнойБазыБСП демонстрационной конфигурации.

**Настройка объектов – владельцев контактной информации**

1. У объекта – владельца контактной информации необходимо создать табличную часть КонтактнаяИнформация со следующими обязательными реквизитами:

Таблица 3.45.

| Имя | Тип значения | Подсказка |
| --- | --- | --- |
| Тип | ПеречислениеСсылка.ТипыКонтактнойИнформации | Тип контактной информации (телефон, адрес и т. п.) |
| Вид | СправочникСсылка.ВидыКонтактнойИнформации | Вид контактной информации |
| Представление | Строка (500) | Представление контактной информации для отображения в формах |
| Значение | Строка неограниченной длины | Служебное поле для хранения контактной информации |
| Страна | Строка (100) | Страна (заполняется для адреса) |
| Регион | Строка (50) | Регион (заполняется для адреса) |
| Город | Строка (50) | Город (заполняется для адреса) |
| АдресЭП | Строка (100) | Адрес электронной почты |
| ДоменноеИмяСервера | Строка (100) | Доменное имя сервера электронной почты или веб-страницы |
| НомерТелефона | Строка (20) | Полный номер телефона |
| НомерТелефонаБезКодов | Строка (20) | Номер телефона без кодов и добавочного номера |
| ЗначенияПолей | Строка неограниченной длины | Служебное поле для хранения контактной информации для поддержания обратной совместимости при обмене данными. |

Для реквизитов Вид и Тип необходимо включить индексирование.

Для всех строковых реквизитов ограниченной длины следует устанавливать индексы по необходимости. Т. е. индексирование должно быть включено только для тех реквизитов, которые используются для выборки данных.

Кроме того, для задействования дополнительных возможностей подсистемы список реквизитов табличной части КонтактнаяИнформация может также включать в себя:

Таблица 3.46.

| Имя | Тип значения | Подсказка |
| --- | --- | --- |
| ИдентификаторСтрокиТабличнойЧасти \* | Число (7,0) | Идентификатор строки табличной части |
| ВидДляСписка\*\* | СправочникСсылка.ВидыКонтактнойИнформации | Вид контактной информации отображаемый в списках |
| ДействуетС \*\*\* | Дата | Дата, с которой действует запись контактной информации |

\* если предполагается хранение контактной информации для табличной части объекта. В этом случае необходимо также добавить этот же реквизит в табличную часть объекта. Пример реализации см. в документе \_ДемоЗаказПокупателя демонстрационной конфигурации.

\*\* если предполагается [вывод полей контактной информации в списках и отчетах](https://its.1c.ru/db/content/bsp301doc/src/3.25.%20%D0%BA%D0%BE%D0%BD%D1%82%D0%B0%D0%BA%D1%82%D0%BD%D0%B0%D1%8F%20%D0%B8%D0%BD%D1%84%D0%BE%D1%80%D0%BC%D0%B0%D1%86%D0%B8%D1%8F.htm?_=1542292879#_вывод_полей_контактной).

\*\*\* если предполагается [хранение истории изменения контактной информации](https://its.1c.ru/db/content/bsp301doc/src/3.25.%20%D0%BA%D0%BE%D0%BD%D1%82%D0%B0%D0%BA%D1%82%D0%BD%D0%B0%D1%8F%20%D0%B8%D0%BD%D1%84%D0%BE%D1%80%D0%BC%D0%B0%D1%86%D0%B8%D1%8F.htm?_=1542292879#_хранение_истории_изменений_1).

2. Изменить форму элемента:

* ● Если предполагается хранение контактной информации для объекта, то в форме элемента создать группу или страницу с именем ГруппаКонтактнаяИнформация и задать ей заголовок – Адреса, телефоны (или другой).
* ● Если предполагается хранение контактной информации для табличной части объекта, то создать группу колонок с именем <ИмяТабличнойЧасти>ГруппаКонтактнаяИнформация в нужной табличной части объекта. Например, для табличной части Партнеры группа контактной информации должна иметь вид ПартнерыГруппаКонтактнаяИнформация.

3. Изменить модуль формы элемента.

* ● В обработчики событий формы ПриСозданииНаСервере, ПриЧтенииНаСервере, ОбработкаПроверкиЗаполненияНаСервере и ПередЗаписьюНаСервере вставить строки из соответствующих процедур, располагающихся ниже. Если предполагается хранение контактной информации для табличной части объекта, то в обработчик события формы ПослеЗаписиНаСервере вставить строки из соответствующей процедуры ниже. Добавляемые строки должны располагаться после проверок, которые могут вызвать отказ в событии.

#Область ОбработчикиСобытийФормы

&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

// СтандартныеПодсистемы.КонтактнаяИнформация

УправлениеКонтактнойИнформацией.ПриСозданииНаСервере(ЭтотОбъект, Объект, "ГруппаКонтактнаяИнформация", ПоложениеЗаголовкаЭлементаФормы.Лево);

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

КонецПроцедуры

&НаСервере

Процедура ПриЧтенииНаСервере(ТекущийОбъект)

// СтандартныеПодсистемы.КонтактнаяИнформация

УправлениеКонтактнойИнформацией.ПриЧтенииНаСервере(ЭтотОбъект, ТекущийОбъект);

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

КонецПроцедуры

&НаСервере

Процедура ОбработкаПроверкиЗаполненияНаСервере(Отказ, ПроверяемыеРеквизиты)

// СтандартныеПодсистемы.КонтактнаяИнформация

УправлениеКонтактнойИнформацией.ОбработкаПроверкиЗаполненияНаСервере(ЭтотОбъект, Объект, Отказ);

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

КонецПроцедуры

&НаСервере

Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

// СтандартныеПодсистемы.КонтактнаяИнформация

УправлениеКонтактнойИнформацией.ПередЗаписьюНаСервере(ЭтотОбъект, ТекущийОбъект);

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

КонецПроцедуры

&НаСервере

Процедура ПослеЗаписиНаСервере(ТекущийОбъект, ПараметрыЗаписи)

// СтандартныеПодсистемы.КонтактнаяИнформация

УправлениеКонтактнойИнформацией.ПослеЗаписиНаСервере(ЭтотОбъект, ТекущийОбъект);

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

КонецПроцедуры

#КонецОбласти

где <ГруппаКонтактнаяИнформация>, ссылка на элемент формы – контейнер, в который будут добавляться элементы для редактирования контактной информации. Например:

УправлениеКонтактнойИнформацией.ПриСозданииНаСервере(ЭтотОбъект, Объект, "ГруппаКонтактнаяИнформация");

* ● В вызове процедуры УправлениеКонтактнойИнформацией.ПриСозданииНаСервере в качестве третьего параметра нужно указать имя элемента, в котором будут располагаться создаваемые поля ввода. Четвертый (необязательный) параметр позволяет задать положение заголовка элементов контактной информации. Заголовки могут располагаться сверху и слева (значения параметра ПоложениеЗаголовкаЭлементаФормы.Лево и ПоложениеЗаголовкаЭлементаФормы.Верх соответственно).

4. Перенести блок процедур контактной информации, расположенный ниже, в модуль формы объекта – владельца контактной информации.

// СтандартныеПодсистемы.КонтактнаяИнформация

&НаКлиенте

Процедура Подключаемый\_КонтактнаяИнформацияПриИзменении(Элемент)

УправлениеКонтактнойИнформациейКлиент.ПриИзменении(ЭтотОбъект, Элемент);

КонецПроцедуры

&НаКлиенте

Процедура Подключаемый\_КонтактнаяИнформацияНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)

УправлениеКонтактнойИнформациейКлиент.НачалоВыбора(ЭтотОбъект, Элемент, , СтандартнаяОбработка);

КонецПроцедуры

&НаКлиенте

Процедура Подключаемый\_КонтактнаяИнформацияПриНажатии(Элемент, СтандартнаяОбработка)

УправлениеКонтактнойИнформациейКлиент.НачалоВыбора(ЭтотОбъект, Элемент, , СтандартнаяОбработка);

КонецПроцедуры

&НаКлиенте

Процедура Подключаемый\_КонтактнаяИнформацияОчистка(Элемент, СтандартнаяОбработка)

УправлениеКонтактнойИнформациейКлиент.Очистка(ЭтотОбъект, Элемент.Имя);

КонецПроцедуры

&НаКлиенте

Процедура Подключаемый\_КонтактнаяИнформацияВыполнитьКоманду(Команда)

УправлениеКонтактнойИнформациейКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда.Имя);

КонецПроцедуры

&НаКлиенте

Процедура Подключаемый\_КонтактнаяИнформацияАвтоПодбор(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка)

УправлениеКонтактнойИнформациейКлиент.АвтоПодбор(Текст, ДанныеВыбора, СтандартнаяОбработка);

КонецПроцедуры

&НаКлиенте

Процедура Подключаемый\_КонтактнаяИнформацияОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)

УправлениеКонтактнойИнформациейКлиент.ОбработкаВыбора(ЭтотОбъект, ВыбранноеЗначение, Элемент.Имя, СтандартнаяОбработка);

КонецПроцедуры

&НаСервере

Процедура Подключаемый\_ОбновитьКонтактнуюИнформацию(Результат)

УправлениеКонтактнойИнформацией.ОбновитьКонтактнуюИнформацию(ЭтотОбъект, Объект, Результат);

КонецПроцедуры

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

**Настройка прав доступа пользователей**

Для настройки прав доступа пользователей к данным подсистемы «Контактная информация» следует использовать роли, перечисленные ниже.

Таблица 3.47.

| № | Роли и их назначение |
| --- | --- |
| 1. | БазовыеПраваБСП (из подсистемы «Базовая функциональность»)  Чтение видов контактной информации и списка стран |
| 2. | ДобавлениеИзменениеВидовКонтактнойИнформации  Ведение списка стран и видов контактной информации |
| 3. | ПолныеПрава (из подсистемы «Базовая функциональность»)  Ведение видов контактной информации, списка стран, а также удаление помеченных на удаление объектов подсистемы |

Для просмотра и редактирования контактной информации конкретных объектов требуются роли для просмотра и редактирования самих объектов-владельцев контактной информации.

Примеры настройки прав доступа пользователей приведены ниже.

Таблица 3.48.

| № | Группа пользователей и ее функции | Состав ролей |
| --- | --- | --- |
| 1. | Администратор | ● ПолныеПрава (из подсистемы «Базовая функциональность») |
| 2. | Ответственный за нормативно-справочную информацию (НСИ): ведение видов контактной информации, списка стран, а также всей остальной НСИ | ● БазовыеПраваБСП (из подсистемы «Базовая функциональность»),  ● ЗапускТонкогоКлиента (из подсистемы «Базовая функциональность»),  ● ДобавлениеИзменениеВидовКонтактнойИнформации |
| 3. | Менеджер по закупкам: ведение списка номенклатуры, ведение списка стран мира (для ввода стран происхождения товаров) | ● БазовыеПраваБСП (из подсистемы «Базовая функциональность»),  ● ЗапускТонкогоКлиента (из подсистемы «Базовая функциональность»),  ● ДобавлениеИзменениеВидовКонтактнойИнформации,  ● <ДобавлениеИзменениеНоменклатуры> |

**Особые случаи внедрения подсистемы**

**Вывод полей контактной информации в списках и отчетах**

Для вывода контактной информации в динамических списках и отчетах необходимо выполнить следующую настройку. В объекте-владельце контактной информации в табличную часть КонтактнаяИнформация добавить реквизит ВидДляСписка с типом СправочникСсылка.ВидКонтактнойИнформации, затем в форме Дополнительные характеристики объекта данных добавить дополнительную характеристику:

Таблица 3.49.

|  |  |  |
| --- | --- | --- |
| Виды характеристик | | |
| Поле ключа | Поле отбора видов | Значение отбора видов |
| Справочник.ВидыКонтактнойИнформации | | |
| Ссылка | Родитель | <Предопределенная группа справочника ВидыКонтактнойИнформации> |

Таблица 3.50.

|  |  |  |
| --- | --- | --- |
| Значения характеристик | | |
| Поле объекта | Поле вида | Поле значения |
| Справочник.<Имя объекта с контактной информацией>.ТабличнаяЧасть.КонтактнаяИнформация | | |
| Ссылка | ВидДляСписка | Представление |

где <Предопределенная группа (элемент) справочника ВидыКонтактнойИнформации> – предопределенная группа(элемент), созданная на этапе формирования видов контактной информации.

Для отображения контактной информации в списках, в форме списка в меню Еще выбрать пункт Изменить форму. В таблице Элементы формы выбрать реквизит Ссылка, нажать кнопку Добавить поля в командной панели формы и далее в открывшемся списке полей выбрать нужные поля контактной информации для отображения.

См. пример реализации в справочнике \_ДемоКонтрагенты демонстрационной конфигурации.

**Создание статических элементов управления**

Создание статических реквизитов контактной информации позволяет:

* ● добавлять элементы контактной информации в различные части формы (например, вынести самые важные виды контактной информации в шапку);
* ● изменять внешний вид и свойства элементов контактной информации без внесения изменений в типовую конфигурацию;
* ● повысить скорость открытия формы – владельца контактной информации.

Для создания статических элементов контактной информации необходимо:

* ● принять решение о видах контактной информации, элементы управления которых должны создаваться вручную;
* ● в обработчике ПриСозданииНаСервере добавить выбранные виды в массив и передать его в качестве пятого параметра в процедуру УправлениеКонтактнойИнформацией.ПриСозданииНаСервере;
* ● добавить в форму реквизит ПараметрыКонтактнойИнформации, тип – произвольный;
* ● добавить в форму реквизит КонтактнаяИнформацияОписаниеДополнительныхРеквизитов, тип – таблица значений с колонками:
* ● ИмяРеквизита – Строка;
* ● Вид – СправочникСсылка.ВидыКонтактнойИнформации;
* ● Тип – ПеречислениеСсылка.ТипыКонтактнойИнформации;
* ● Значение – Строка;
* ● Представление – Строка;
* ● Комментарий – Строка;
* ● ЭтоРеквизитТабличнойЧасти – Булево;
* ● ЭтоИсторическаяКонтактнаяИнформация – Булево;
* ● МеждународныйФорматАдреса – Булево;
* ● ИмяЭлементаДляРазмещения – Строка;
* ● ЗначенияПолей – СписокЗначений, Строка;
* ● для каждого вида контактной информации добавить реквизит с именем вида КонтактнаяИнформацияПоле<ИмяВидаКонтактнойИнформации>;
* ● добавить на форму элементы:
* ● для каждого вида контактной информации добавить на форму группу с именем ГруппаКонтактнаяИнформацияПоле <ИмяВидаКонтактнойИнформации>. Свойства: Отображение – Нет, Группировка – Горизонтальная, ОтображатьЗаголовок – Ложь;
* ● в созданную группу перетащить ранее созданный реквизит с именем вида КонтактнаяИнформацияПоле<ИмяВидаКонтактнойИнформации>, установив соответствующее отображение заголовка (Лево или Верх) в зависимости от положения заголовка, передаваемого в процедуру УправлениеКонтактнойИнформацией.ПриСозданииНаСервере;
* ● для добавления действия необходимо создать команду с именем вида КомандаКонтактнаяИнформацияПоле<ИмяВидаКонтактнойИнформации>, отображение Картинка. Затем эту команду необходимо перетащить в ранее созданную группу ГруппаКонтактнаяИнформацияПоле <ИмяВидаКонтактнойИнформации>. Картинка команды, заголовок и подисказка устанавливаются в зависимости от типа контактной информации:
* ● для типа Адрес действие добавляется только в том случае, если имеется несколько видов контактной информации типа Адрес. В этом случае для команды устанавливается картинка ПереместитьВлево, заголовок Заполнить, подсказка Заполнить адрес из другого поля;
* ● для типа ВебСтраница картинка КонтактнаяИнформацияПерейтиПоСсылке, заголовок Перейти, подсказка Перейти по ссылке;
* ● для типа АдресЭлектроннойПочты действие устанавливается только при наличии подсистемы «[РаботаСПочтовымиСообщениями](https://its.1c.ru/db/content/bsp301doc/src/3.48.%20работа%20с%20почтовыми%20сообщениями.htm?_=1542292879#_работа_с_почтовыми)». При этом устанавливается картинка ОтправитьЭлектронноеПисьмо, заголовок Написать письмо, подсказка Написать письмо;
* ● для типа Телефон при наличии подсистемы «[ОтправкаSMS](https://its.1c.ru/db/content/bsp301doc/src/3.32.%20обновление%20конфигурации.htm?_=1542292879#_отправка_sms)» используется картинка ПозвонитьИлиОтправитьSMS, заголовок Позвонить или отправить SMS, подсказка Позвонить или отправить SMS. Если подсистемы «[ОтправкаSMS](https://its.1c.ru/db/content/bsp301doc/src/3.32.%20обновление%20конфигурации.htm?_=1542292879#_отправка_sms)» нет, то используется картинка Позвонить, заголовок Позвонить, подсказка Позвонить по телефону;
* ● для типа Skype необходимо установить картинку, заголовок и подсказку Skype.

Виды контактной информации, добавляемые в форму вручную, рекомендуется сделать недоступными для редактирования пользователем. Это можно сделать в обработчике обновления при помощи процедуры УстановитьСвойстваВидаКонтактнойИнформации из общего модуля УправлениеКонтактнойИнформацией. За недоступность редактирования пользователем отвечает свойство ЗапретитьРедактированиеПользователем.

Пример использования см. в форме элемента справочника \_ДемоКонтрагенты демонстрационной конфигурации.

**Отложенная инициализация элементов контактной информации**

Если элементы контактной информации (или их часть) располагаются на отдельной закладке и работа с ними не является основным сценарием работы с формой, то можно увеличить скорость открытия формы путем переноса создания элементов контактной информации с момента открытия формы на момент перехода на закладку контактной информации.

Использование отложенной инициализации также накладывает следующие ограничения:

* ● невозможно перетаскивать элементы со страницы контактной информации,
* ● в некоторых случаях возможны «скачки» формы.

Для использования отложенной инициализации необходимо:

* ● добавить в форму реквизит ПараметрыКонтактнойИнформации, тип – произвольный;
* ● добавить в форму реквизит КонтактнаяИнформацияОписаниеДополнительныхРеквизитов, тип – таблица значений. Описание колонок и их типов см. в предыдущем разделе;
* ● в обработчик УправлениеКонтактнойИнформацией.ПриСозданииНаСервере передать в качестве шестого параметра (ОтложеннаяИнициализация) значение Истина;
* ● для страницы контактной информации установить свойство РазрешитьИзменениеСостава в значение Ложь;
* ● для группы страниц, содержащей страницу контактной информации, добавить обработчик ПриСменеСтраницы, в который добавить код:

// СтандартныеПодсистемы.КонтактнаяИнформация

Если ТекущаяСтраница.Имя = ЭтотОбъект.ПараметрыКонтактнойИнформации.ГруппаДляРазмещения И Не

     ЭтотОбъект.ПараметрыКонтактнойИнформации.ВыполненаОтложеннаяИнициализация Тогда

  КонтактнаяИнформацияПриСменеСтраницы();

КонецЕсли;

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

* ● в блок процедур контактной информации добавить процедуру:

&НаСервере

Процедура КонтактнаяИнформацияПриСменеСтраницы()

УправлениеКонтактнойИнформацией.ВыполнитьОтложеннуюИнициализацию(ЭтотОбъект, Объект);

КонецПроцедуры

* ● если на странице контактной информации нет статических элементов, то добавить декорацию с именем ПустаяДекорацияКонтактнаяИнформация.

Пример использования см. в форме элемента справочника \_ДемоКонтрагенты демонстрационной конфигурации.

**Хранение истории изменений контактной информации**

В случае если для ведения учета важно хранить не только текущие значения полей контактной информации, но и их историю, а также получать значение на указанную дату, необходимо настроить хранение истории изменения контактной информации:

1. Принять решение по поводу состава объектов – владельцев контактной информацией и видов контактной информации, у которых необходимо хранить историю изменения контактной информации. Например, у справочника Организации это может быть юридический адрес.

2. Добавить в табличную часть КонтактнаяИнформация этих объектов реквизит ДействуетС с типом Дата.

3. Написать обработчик обновления, устанавливающий флаг о необходимости хранения история изменений для вида контактной информации. Пример кода обработчика:

ПараметрыВида = УправлениеКонтактнойИнформацией.ПараметрыВидаКонтактнойИнформации("Адрес");

ПараметрыВида.ХранитьИсториюИзменений = Истина;

  УправлениеКонтактнойИнформацией.УстановитьСвойстваВидаКонтактнойИнформации(ПараметрыВида);

Для получения контактной информации на заданную дату необходимо в процедурах и функциях КонтактнаяИнформацияОбъекта, КонтактнаяИнформацияОбъектов, СоздатьВТКонтактнаяИнформация, ТаблицаКонтактнойИнформацииОбъекта указывать параметр Дата (например, дату документа в коде печатных форм). Для записи контактной информации на заданную дату следует использовать процедуры ЗаполнитьКонтактнуюИнформациюОбъектов и ЗаполнитьКонтактнуюИнформациюОбъекта аналогичным образом. При включенной истории хранения изменений не допускается возможность ввода нескольких значений контактной информации. Более подробную информацию см. в комментариях к процедурам.

Пример реализации см. в демонстрационной конфигурации в справочнике \_ДемоОрганизации для вида контактной информации Юридический адрес.

**Заполнение и редактирование контактной информации одного объекта в форме другого объекта**

Имеется возможность выводить контактную информацию объекта в отдельной форме или форме другого объекта. Такая возможность позволяет редактировать контактную информацию объекта без необходимости открытия формы владельца контактной информации.

Например, если необходимо для вывода к уже ранее размещенной контактной информации элемента справочника Демо: Контакные лица партнеров выводить контактную информацию реквизита ФизическоеЛицо ссылающегося на элемент справочника Демо: Физические лица, то следует сделать следующие:

* ● создать реквизит формы ФизическоеЛицо с типом СправочникОбъект.\_ДемоФизическиеЛица, содержащий объект владельца редактируемой контактной информацией;
* ● на форме создать группу или страницу с именем ГруппаКонтактнаяИнформацияФизическоеЛицо – контейнер, в который будут добавляться элементы формы для редактирования контактной информации физического лица;
* ● в обработчиках событий формы ПриСозданииНаСервере, ПриЧтенииНаСервере и ПередЗаписьюНаСервере для заполнения и сохранения контактной информации физического лица добавить аналогичные вызовы, где в качестве параметров указать реквизит формы ФизическоеЛицо и группу размещения контактной информации:

#Область ОбработчикиСобытийФормы

&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

// СтандартныеПодсистемы.КонтактнаяИнформация

УправлениеКонтактнойИнформацией.ПриСозданииНаСервере(ЭтотОбъект, Объект,, ПоложениеЗаголовкаЭлементаФормы.Лево);

УправлениеКонтактнойИнформацией.ПриСозданииНаСервере(ЭтотОбъект, ФизическоеЛицо, "ГруппаКонтактнаяИнформацияФизическогоЛица", ПоложениеЗаголовкаЭлементаФормы.Лево);

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

КонецПроцедуры

&НаСервере

Процедура ПриЧтенииНаСервере(ТекущийОбъект)

// СтандартныеПодсистемы.КонтактнаяИнформация

Если ЗначениеЗаполнено(ТекущийОбъект.ФизическоеЛицо) Тогда

ЗначениеВРеквизитФормы(ТекущийОбъект.ФизическоеЛицо.ПолучитьОбъект(), "ФизическоеЛицо");

КонецЕсли;

УправлениеКонтактнойИнформацией.ПриЧтенииНаСервере(ЭтотОбъект, ФизическоеЛицо, "ГруппаКонтактнаяИнформацияФизическогоЛица");

УправлениеКонтактнойИнформацией.ПриЧтенииНаСервере(ЭтотОбъект, Объект);

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

КонецПроцедуры

&НаСервере

Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

// СтандартныеПодсистемы.КонтактнаяИнформация

УправлениеКонтактнойИнформацией.ПередЗаписьюНаСервере(ЭтотОбъект, ТекущийОбъект);

УправлениеКонтактнойИнформацией.ПередЗаписьюНаСервере(ЭтотОбъект, ФизическоеЛицоОбъект);

// Конец СтандартныеПодсистемы.КонтактнаяИнформация

КонецПроцедуры

&НаСервере

Процедура ПриЗаписиНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

ФизическоеЛицоОбъект = РеквизитФормыВЗначение("ФизическоеЛицо");

ФизическоеЛицоОбъект.Записать();

ЗначениеВРеквизитФормы(ФизическоеЛицоОбъект, "ФизическоеЛицо");

КонецПроцедуры

#КонецОбласти

* ● добавить код блокирующий для изменения элемент справочника Демо: Физические лица, контактная информация которого выведена на форму:
* ● для этого в обработчики события ПриОткрытии подключаем обработчик проверяющий необходимость блокировки объекта физического лица:

&НаКлиенте

Процедура ПриОткрытии(Отказ)

ПодключитьОбработчикОжидания("ПроверитьНеобходимостьБлокировкиФизическогоЛица", 1, Ложь);

КонецПроцедуры

* ● и процедуру, вызываемую этим обработчиком для попытки блокировки элемента справочника физического лица, если информация на форме была изменена:

&НаКлиенте

Процедура ПроверитьНеобходимостьБлокировкиФизическогоЛица()

Если Модифицированность Тогда

Попытка

ЗаблокироватьДанныеДляРедактирования(ФизическоеЛицо.Ссылка, ФизическоеЛицо.ВерсияДанных, ФормаУникальныйИдентификатор);

ОтключитьОбработчикОжидания("ПроверитьНеобходимостьБлокировкиФизическогоЛица");

Исключение

ВызватьИсключение НСтр("ru = 'Данные контактого лица не могут быть записаны, т.к. личные данные физического лица недоступны для изменения.

|Возможно, эти данные физического лица редактируются другим пользователем.'");

Прочитать();

КонецПопытки;

КонецЕсли;

КонецПроцедуры

Пример использования см. в форме элемента справочника \_ДемоКонтактныеЛицаПартнеров демонстрационной конфигурации.

**Добавление произвольных реквизитов с контактной информацией**

Имеется возможность хранить значения полей контактной информации не только в стандартной табличной части КонтактнаяИнформация, но и в произвольных реквизитах произвольных объектов конфигурации. Такая возможность может быть востребована для добавления к объектам отдельных полей с контактной информацией.

Например, необходимо хранить данные адреса доставки в документе ЗаказПокупателя. При этом в форме документа должно быть поле Адрес доставки, редактируемое с помощью стандартной формы ввода адреса, и поля Дата доставки, Метро, Комментарий. При этом в заказе покупателя не требуются остальные сервисы подсистемы по заведению других видов контактной информации.

Для решения этой задачи необходимо:

1. Добавить к документу ЗаказПокупателя основные реквизиты:

* ● АдресДоставки типа «строка неограниченной длины». Этот реквизит будет хранить служебные значения контактной информации адреса доставки;
* ● ДатаДоставки типа Дата для хранения даты доставки;
* ● Метро. Ссылка на справочник СтанцииМетро.

2. Добавить к документу ЗаказПокупателя вспомогательные реквизиты, данные в которых будут вычисляться при записи документа по данным реквизита АдресДоставки. Эти реквизиты предназначены для оперативного поиска документов по данным контактной информации, вывода данных на печать и т. п.

* ● АдресДоставкиСтрокой – строка длиной 200 символов;
* ● ГородАдресаДоставки – строка длиной 100 символов.

3. Поместить в форму вспомогательный реквизит ВидКонтактнойИнформацииАдресаДоставки для контроля работы с адресом и инициализировать его при создании формы:

ВидКонтактнойИнформацииАдресаДоставки = Новый Структура;

ВидКонтактнойИнформацииАдресаДоставки.Вставить("Тип", Перечисления.ТипыКонтактнойИнформации.Адрес );

ВидКонтактнойИнформацииАдресаДоставки.Вставить("ТолькоНациональныйАдрес", Ложь);

ВидКонтактнойИнформацииАдресаДоставки.Вставить("ВключатьСтрануВПредставление", Ложь);

ВидКонтактнойИнформацииАдресаДоставки.Вставить("СкрыватьНеактуальныеАдреса", Ложь);

Эта структура заменяет собой соответствующий элемент справочника ВидыКонтактнойИнформации.

4. Поместить в форму документа вспомогательный строковый реквизит ПредставлениеАдресаДоставки. Инициализировать значение реквизита при создании формы:

ПредставлениеАдресаДоставки = УправлениеКонтактнойИнформацией.ПредставлениеКонтактнойИнформации(Объект.АдресДоставки);

* ● создать соответствующее вспомогательному реквизиту поле ввода, установить у него флажок КнопкаВыбора в Истина;
* ● определить обработчики событий для этого элемента:

&НаКлиенте

Процедура ПредставлениеАдресаДоставкиПриИзменении(Элемент)

Текст = Элемент.ТекстРедактирования;

Если ПустаяСтрока(Текст) Тогда

// Очистка данных.

// Cбрасываем как представления,

// так и внутренние значения полей

ПредставлениеАдресаДоставки = "";

КомментарийАдресаДоставки   = "";

Объект.АдресДоставки        = "";

Возврат;

КонецЕсли;

// Формируем внутренние значения полей по тексту

// и параметрам

ПредставлениеАдресаДоставки = Текст;

Объект.АдресДоставки = ЗначенияПолейКонтактнойИнформацииСервер(Текст,

ВидКонтактнойИнформацииАдресаДоставки, КомментарийАдресаДоставки);

КонецПроцедуры

&НаКлиенте

Процедура ПредставлениеАдресаДоставкиНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)

// Если представление было изменено в поле и сразу нажата

// кнопка выбора, то необходимо привести данные в соответствие

// и сбросить внутренние поля для повторного репарсинга

Если Элемент.ТекстРедактирования<>ПредставлениеАдресаДоставки Тогда

ПредставлениеАдресаДоставки = Элемент.ТекстРедактирования;

Объект.АдресДоставки = "";

КонецЕсли;

// Данные для редактирования

ПараметрыОткрытия = Новый Структура;

ПараметрыОткрытия.Вставить("ВидКонтактнойИнформации", ВидКонтактнойИнформацииАдресаДоставки);

ПараметрыОткрытия.Вставить("Значение",      Объект.АдресДоставки);

ПараметрыОткрытия.Вставить("Представление", ПредставлениеАдресаДоставки);

ПараметрыОткрытия.Вставить("Комментарий",   КомментарийАдресаДоставки);

// Переопределямый заголовок формы,

// по умолчанию отобразятся данные по ВидКонтактнойИнформации

ПараметрыОткрытия.Вставить("Заголовок", НСтр("ru='Адрес доставки'"));

УправлениеКонтактнойИнформациейКлиент.ОткрытьФормуКонтактнойИнформации(ПараметрыОткрытия, Элемент );

КонецПроцедуры

&НаКлиенте

Процедура ПредставлениеАдресаДоставкиОчистка(Элемент, СтандартнаяОбработка)

// Сбрасываем как представления,

//  так и внутренние значения полей

ПредставлениеАдресаДоставки = "";

КомментарийАдресаДоставки   = "";

Объект.АдресДоставки        = "";

КонецПроцедуры

&НаКлиенте

Процедура ПредставлениеАдресаДоставкиОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)

СтандартнаяОбработка = Ложь;

Если ТипЗнч(ВыбранноеЗначение)<>Тип("Структура") Тогда

// Отказ от выбора, данные неизменны

Возврат;

КонецЕсли;

ПредставлениеАдресаДоставки = ВыбранноеЗначение.Представление;

КомментарийАдресаДоставки   = ВыбранноеЗначение.Комментарий;

Объект.АдресДоставки        = ВыбранноеЗначение.КонтактнаяИнформация;

КонецПроцедуры

Следует заметить, что если функционал ввода адреса строкой не требуется, то можно обойтись без этого вспомогательного поля ввода, заменив его, например, на гиперссылку. Текст гиперссылки при этом будет представлением адреса, а обработчик нажатия аналогичен обработчику НачалоВыбора.

5. Поместить в форму вспомогательный реквизит КомментарийАдресаДоставки для редактирования комментария, не попадающего в основное представление адреса. Инициализировать его при создании формы:

КомментарийАдресаДоставки =

УправлениеКонтактнойИнформацией.КомментарийКонтактнойИнформации(

Объект.АдресДоставки

);

6. Поместить в форму поле ввода и связать его с реквизитом КомментарийАдресаДоставки. Определить следующие обработчики изменений:

&НаКлиенте

Процедура КомментарийАдресаДоставкиПриИзменении(Элемент)

ЗаполнитьКомментарийАдресаДоставкиСервер();

КонецПроцедуры

// Устанавливаем новый комментарий для адреса доставки

//

&НаСервере

Процедура ЗаполнитьКомментарийАдресаДоставкиСервер()

Если ПустаяСтрока(Объект.АдресДоставки) Тогда

// Необходимо инициализировать данные

Объект.АдресДоставки = ЗначенияПолейКонтактнойИнформацииСервер(ПредставлениеАдресаДоставки,

ВидКонтактнойИнформацииАдресаДоставки, КомментарийАдресаДоставки);

Возврат;

КонецЕсли;

УправлениеКонтактнойИнформацией.КомментарийКонтактнойИнформации(Объект.АдресДоставки,

  КомментарийАдресаДоставки);

КонецПроцедуры

7. Поместить в форму документа поля ввода, связанные с реквизитами объекта ДатаДоставки и Метро.

8. В модуле объекта документа, в обработчике события ПередЗаписью заполнить вспомогательные реквизиты:

ГородДоставки = УправлениеКонтактнойИнформацией.ГородАдресаКонтактнойИнформации(АдресДоставки);

АдресДоставкиСтрокой = УправлениеКонтактнойИнформацией.ПредставлениеКонтактнойИнформации(АдресДоставки);

БСП обеспечивает программный интерфейс для оперирования данными:

* ● методы для разбора контактной информации из строки представления;
* ● методы для формирования представления контактной информации;
* ● методы для получения и установки значений частей контактной информации (например, комментария, страны адреса, города адреса и т. п.);
* ● методы для сравнения объектов контактной информации.

Пример реализации см. в демонстрационной конфигурации в реквизите АдресДоставки документа \_ДемоЗаказПокупателя.

**Отключение неиспользуемых видов контактной информации**

В случае если объект – владелец контактной информации отключен по функциональной опции, имеется возможность отключить неиспользуемый вид контактной информации. Для этого можно воспользоваться свойством Используется вида контактной информации. При установке значения свойства Используется в значение Ложь вид контактной информации перестает отображаться в форме списка, а также в форме объекта – владельца контактной информации. Устанавливать свойство Используется можно как для отдельных видов контактной информации, так и для всей контактной информации объекта владельца (группа видов контактной информации). Для отключения неиспользуемого вида контактной информации необходимо:

* ● Написать обработчик обновления, отключающий неиспользуемые виды контактной информации при переходе на новую версию. Пример кода обработчика:

КонтактныеЛицПартнеров = Справочники.ВидыКонтактнойИнформации.Справочник\_ДемоКонтактныеЛицаПартнеров.ПолучитьОбъект();

КонтактныеЛицПартнеров.Используется = ПолучитьФункциональнуюОпцию("\_ДемоИспользоватьКонтактныеЛицаПартнеров");

ОбновлениеИнформационнойБазы.ЗаписатьДанные(КонтактныеЛицПартнеров);

* ● Добавить аналогичный код в событие при изменении значения функциональной опции. См. пример в событии ПриЗаписи в модуле менеджера значения константы \_ДемоИспользоватьКонтактныеЛицаПартнеров.

**Добавление реквизитов типа «СправочникСсылка.СтраныМира»**

В общем случае при добавлении реквизита типа СправочникСсылка.СтраныМира можно выбирать любой элемент справочника. Но если список выбираемых стран мира должен быть регламентирован (т. е. разрешен выбор стран только из классификатора), то дополнительно следует в свойстве ПараметрыВыбора элемента формы (поля ввода) указать:

* ● РазрешитьДанныеКлассификатора – Булево, Истина;
* ● ТолькоДанныеКлассификатора – Булево, Истина.

Также есть возможность автоматически создавать новые элементы справочника СтраныМира при выборе автоподбором. Для этого необходимо в модуле формы в обработчике события ОбработкаВыбора вставить вызов:

УправлениеКонтактнойИнформациейКлиент.СтранаМираОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка);

Пример использования см. в форме элемента справочника \_ДемоНоменклатура демонстрационной конфигурации.

**Совместное внедрение с другими подсистемами**

* ● [Внедрение подсистемы «Пользователи» без подсистемы «Контактная информация»](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_внедрение_подсистемы_«пользователи»).

**Использование при разработке конфигурации**

При разработке новых или доработке существующих предопределенных видов контактной информации необходимо предусмотреть их обновление при помощи обработчика обновления.

**Автоматическое добавление элементов в справочник «СтраныМира» из классификатора стран мира.**

По умолчанию справочник СтраныМира содержит только один предопределенный элемент Россия. Пользователи с соответствующими правами могут добавлять в справочник новые элементы – как вручную, так и с помощью подбора из классификатора стран мира. При этом новые элементы справочника могут быть автоматически созданы по данным классификатора в процессе выбора и непосредственно при автоподборе в поле ввода страны.

Таким образом, в справочнике СтраныМира содержатся только те страны, которые используются в учете.

**Настройка обмена данными**

Для настройки обмена данными следует руководствоваться общими правилами. В план обмена необходимо включить все объекты метаданных, содержащие данные, кроме регистра сведений УдалитьСтраныМира.

При включении справочника СтраныМира в план обмена между различными прикладными решениями с использованием правил конвертации необходимо настроить в правиле конвертации объекта (ПКО) поиск по ссылке, а затем по полям поиска – составному ключу Код и Наименование.

**Настройка обмена данными с предыдущими версиями**

* ● При синхронизации контактной информации с конфигурациями на базе БСП редакции 2.4 и меньше, необходимо в правилах конвертации настроить правила выгрузки таким образом, чтобы для объектов – владельцев контактной информации исключать выгрузку реквизита Значение табличной части КонтактнаяИнформация;
* ● При синхронизации контактной информации с конфигурациями на базе БСП версии 2.1.2 и меньше необходимо при выгрузке в эту конфигурацию производить конвертацию реквизита ЗначенияПолей табличной части КонтактнаяИнформация при помощи вызова:

Значение = РаботаСАдресами.ПредыдущийФорматКонтактнойИнформацииXML(Значение, Истина)

При использовании правил конвертации для этого необходимо вписать приведенный выше код в обработчик ПриВыгрузке правила конвертации свойства (ПКС) для реквизита ЗначенияПолей табличной части КонтактнаяИнформация.

* ● При синхронизации контактной информации с конфигурациями на базе БСП редакции 2.2 и меньше, необходимо в правилах конвертации настроить правила выгрузки из БСП 2.3.1 в БСП 2.2 таким образом, чтобы для объектов – владельцев контактной информации исключать выгрузку:
* ● реквизита ВидДляСписка табличной части КонтактнаяИнформация;
* ● всех строк табличной части КонтактнаяИнформация с типом контактной информации Skype.
* ● Если табличная часть КонтактнаяИнформация содержит реквизит ДействуетС, то при синхронизации контактной информации с конфигурациями на базе БСП версии 2.3.1 и меньше для видов контактной информации с установленным свойством ХранитьИсториюИзменений необходимо настроить правила обмена следующим образом:
* ● при выгрузке данных – если у вида контактной информации существует несколько записей с разными датами в реквизите ДействуетС, то в выгрузку включается только актуальная (действующая) запись. Все исторические записи игнорируются и в выгрузку не попадают;
* ● при загрузке данных – все записи этого вида контактной информации сохраняются без изменений. Но в случае, когда загружаемая запись отличается от данных текущей (действующей) записи этого вида контактной информации, в табличную часть КонтактнаяИнформация добавляется новая строка с загружаемыми данными, а реквизиту ДействуетС новой строки контактной информации присваивается текущая дата сеанса, т. к. эта запись становится актуальной (действующей).

Пример использования см. в демонстрационной конфигурации, в макетах ПравилаОбмена и ПравилаОбменаКорреспондента плана обмена \_ДемоОбменСБиблиотекойСтандартныхПодсистем225.